5 REM--AHOY!--JAN ISSUE--SEQUENTIAL FILES--PROG PAGE 67
10 CLR:DIMN$(100),P$(100):PRINTCHR$(147)
20 PRINT"    PHONE BOOK SEQUENTIAL FILE DEMO"
100 PRINT:PRINT:PRINT"START NEW FILE (Y/N)? ";
110 GETA$:IFA$<>"Y"ANDA$<>"N"THEN110
120 IFA$="N"THENPRINT"NO":GOTO200
130 PRINT"YES":OPEN2,8,2,"@0:PHONES,S,W"
140 PRINT#2,"0":CLOSE2
200 OPEN2,8,2,"PHONES,S,R":INPUT#2,N
210 FORX=1TON:INPUT#2,N$(X),P$(X):NEXT
220 CLOSE2
230 PRINT"[147]";N;" ENTRIES EXIST IN FILE"
300 PRINT:PRINT"1- ADD ENTRIES"
310 PRINT"2- DELETE ENTRIES"
320 PRINT"3- DISPLAY LIST"
330 PRINT"4- SEARCH FOR NAME"
340 PRINT"5- EXIT PROGRAM"
350 PRINT:PRINT"ENTER CHOICE: ";
360 GETA$:A=VAL(A$):IFA<1ORA>5THEN360
370 IFA=1THEN400
375 IFA=2THEN450
380 IFA=3THEN500
385 IFA=4THEN550
390 IFA=5THEN600
400 PRINTCHR$(147);"ENTER NAME, PHONE NUMBER:":N$="":P$="":INPUTN$,P$
410 IFN$=""THEN230
420 N=N+1:N$(N)=N$:P$(N)=P$:GOTO230
450 PRINTCHR$(147);"ENTER NAME,TO DELETE:":N$="":INPUTN$:IFN$=""THEN230
460 F=0:FORX=1TON:IFN$=N$(X)THENF=X
470 NEXT:IFF<>0THEN480
472 PRINT"NOT FOUND.  HIT A KEY."
475 GETA$:IFA$=""THEN475
477 GOTO230
480 N=N-1:FORX=FTON:N$(X)=N$(X+1):P$(X)=P$(X+1):NEXT
490 GOTO230
500 PRINTCHR$(147)
510 FORX=1TON:PRINTN$(X),P$(X):NEXT:PRINT:PRINT"ALL DONE.  HIT A KEY."
520 GETA$:IFA$=""THEN520
530 GOTO230
550 PRINTCHR$(147);"ENTER NAME TO SEARCH FOR:":N$="":INPUTN$:IFN$=""THEN230
560 F=0:FORX=1TON:IFN$=N$(X)THENF=X
565 NEXT
570 IFF<>0THEN580
575 PRINT"NOT FOUND.  HIT A KEY."
577 GETA$:IFA$=""THEN577
578 GOTO230
580 PRINTN$(F),P$(F):PRINT:PRINT"HIT A KEY."
585 GETA$:IFA$=""THEN585
590 GOTO230
600 OPEN2,8,2,"@0:PHONES,S,W":PRINT#2,N
610 FORX=1TON:PRINT#2,N$(X):PRINT#2,P$(X):NEXT:CLOSE2